home *** CD-ROM | disk | FTP | other *** search
/ Collection of Tools & Utilities / Collection of Tools and Utilities.iso / dskut / apl2pc.zip / APL2PC.BAS next >
BASIC Source File  |  1985-12-10  |  5KB  |  108 lines
  1. 10 CLS : KEY OFF : LOCATE 3,1
  2. 20 PRINT "          VisiCalc" : PRINT : PRINT "    A>  APPLE --> IBM" : PRINT "    B>  IBM --> APPLE"
  3. 25 PRINT :PRINT
  4. 30 PRINT "          WordStar" : PRINT : PRINT "    C>  APPLE --> IBM" : PRINT "    D>  IBM --> APPLE"
  5. 35 PRINT :PRINT
  6. 40 PRINT "           Other" : PRINT : PRINT "    E>  APPLE --> IBM" : PRINT "    F>  IBM --> APPLE"
  7. 50 PRINT :PRINT : PRINT : PRINT "    G>  Exit to Basic"
  8. 60 GOSUB 1260
  9. 70 IF T$ = "A" THEN 200 ELSE IF T$ = "B" THEN 100 ELSE IF T$ = "C" THEN 500 ELSE IF T$ = "D" THEN 700 ELSE IF T$ = "E" THEN 400 ELSE IF T$ = "F" THEN 300 ELSE IF T$ = "G" THEN CLS : NEW : END ELSE 60
  10. 80 '
  11. 90 '
  12. 100 BNR$ = "       VisiCalc:  IBM --> APPLE" : EXT$ = "" : GOTO 310
  13. 200 BNR$ = "       VisiCalc:  APPLE --> IBM" : EXT$ = ".VC" : GOTO 410
  14. 210 '
  15. 220 '
  16. 230 '
  17. 300 BNR$ = "        Other:  IBM --> APPLE" : EXT$ = ".APL"
  18. 310 GOSUB 1000
  19. 320 WHILE NOT(EOF(1))
  20. 330    A$ = INPUT$(1,1)
  21. 340    IF A$ <> CHR$(10) THEN PRINT #2, A$;
  22. 350 WEND
  23. 360 CLOSE : GOTO 1180
  24. 370 '
  25. 380 '
  26. 390 '
  27. 400 BNR$ = "        Other:  APPLE --> IBM" : EXT$ = ".IBM"
  28. 410 GOSUB 1000
  29. 420 WHILE NOT(EOF(1))
  30. 430    A$ = INPUT$(1,1)
  31. 440    IF A$ <> CHR$(10) THEN PRINT #2, A$; : IF ASC(A$) = 13 THEN PRINT #2,CHR$(10);
  32. 450 WEND
  33. 460 PRINT #2,CHR$(13);CHR$(10);
  34. 465 IF EXT$ = ".VC" THEN FOR I = 1 TO 256 : PRINT #2,"" : NEXT
  35. 470 CLOSE : GOTO 1180
  36. 480 '
  37. 490 '
  38. 500 BNR$ = "       Wordstar:  APPLE --> IBM" : EXT$ = ".WSI"
  39. 510 GOSUB 1000 : AL$ = "" : AL = 0
  40. 520 WHILE NOT(EOF(1))
  41. 530   A$ = INPUT$(1,1) : IF A$ <> CHR$(0) THEN A = ASC(A$) ELSE A = 0
  42. 540   IF AL = 0 THEN 670
  43. 550     IF AL <> 13 THEN 600
  44. 560        IF RFLAG THEN AL$ = CHR$(13) + CHR$(10) : GOTO 660
  45. 570        IF A = 13 THEN RFLAG = NOT(0) : AL$ = CHR$(13) + CHR$(10) : GOTO 660
  46. 580        AL$ = CHR$(13 + 128) + CHR$(10) : GOTO 660
  47. 600     RFLAG = 0
  48. 610     IF A <> 13 THEN 650
  49. 620        IF AL$ = " " THEN 660 ELSE AL$ = CHR$(AL + 128) + " " : GOTO 660
  50. 650     IF A$ = " " THEN AL = AL + 128 : AL$ = CHR$(AL)
  51. 660   PRINT #2,AL$;
  52. 670   AL$ = A$ : AL = A
  53. 680 WEND
  54. 685 IF AL <> 13 THEN PRINT #2,AL$;
  55. 690 PRINT #2,"" : CLOSE : GOTO 1180
  56. 700 BNR$ = "       Wordstar:  IBM --> APPLE" : EXT$ = ".TXT"
  57. 710 GOSUB 1000
  58. 720 WHILE NOT(EOF(1))
  59. 730    A$ = INPUT$(1,1)
  60. 740    IF A$ <> CHR$(0) THEN PRINT #2, A$;
  61. 750 WEND
  62. 760 PRINT #2,"" : CLOSE : GOTO 1180
  63. 770 '
  64. 780 '
  65. 790 '
  66. 1000 GOSUB 1210 : LOCATE 9,1 : PRINT "(Press RETURN to return to main menu.)" : LOCATE 14,1 : INPUT "FILENAME"; FL$
  67. 1010 IF FL$ = "" THEN 10
  68. 1020 IF INSTR(FL$,".") THEN FLA$ = LEFT$(FL$,INSTR(FL$,".")-1) ELSE FLA$ = FL$
  69. 1030 FLA$ = LEFT$(FLA$,8+ INSTR(FLA$,":")) + EXT$
  70. 1040 ON ERROR GOTO 1310
  71. 1050 OPEN FL$ FOR INPUT AS #1
  72. 1055 IF FL$ <> FLA$ THEN 1060
  73. 1057      GOSUB 1210 : LOCATE 8,1 : PRINT "Source file and target file have" : PRINT : PRINT "the same name:  "; FL$ : PRINT : PRINT : INPUT "New target filename"; FLA$
  74. 1060 ON ERROR GOTO 1300
  75. 1070 FLAG = 0 : OPEN FLA$ FOR INPUT AS #2
  76. 1080 ON ERROR GOTO 0 : CLOSE #2
  77. 1090 IF FLAG THEN 1130
  78. 1100      GOSUB 1210 : LOCATE 8,1 : PRINT "File ";FLA$; " already exists."
  79. 1110      PRINT : PRINT "New target filename?": PRINT : PRINT "(Press return to overwrite "; FLA$; ")" : PRINT
  80. 1120      INPUT T$ : IF T$ = "" THEN 1130 ELSE FLA$ = T$ : GOTO 1060
  81. 1130 GOSUB 1210 : LOCATE 7,5 : PRINT "SOURCE FILE . . . "FL$ : PRINT :PRINT :PRINT "    TARGET FILE . . . "; FLA$ : LOCATE 15,10 : PRINT "* * WORKING * *"
  82. 1135 ON ERROR GOTO 1500
  83. 1140 OPEN FLA$ FOR OUTPUT AS #2
  84. 1145 ON ERROR GOTO 0 : RETURN
  85. 1150 '
  86. 1160 '
  87. 1170 '
  88. 1180 LOCATE 15,10 : PRINT "  * * DONE * *      "
  89. 1190 PRINT :PRINT :PRINT "    (Press any key to continue)"
  90. 1200 GOSUB 1260 : GOTO 10
  91. 1210 CLS : PRINT BNR$ : PRINT STRING$(39,196) : RETURN
  92. 1220 '
  93. 1230 '
  94. 1240 '
  95. 1250 '
  96. 1260 T$ = INKEY$ : IF T$ <> "" THEN 1260
  97. 1270 T$ = INKEY$ : IF T$ = "" THEN 1270
  98. 1280 IF T$ >= "a" AND T$ <= "z" THEN T$ = CHR$(ASC(T$)-32)
  99. 1290 RETURN
  100. 1300 FLAG = 1 : RESUME 1080
  101. 1310 GOSUB 1210
  102. 1320 LOCATE 11,1 :PRINT "Unable to find file ";FL$ :PRINT :PRINT "Press any key to continue."
  103. 1330 GOSUB 1260 : RESUME 1000
  104. 1500 GOSUB 1210 : LOCATE 4,1 : PRINT "  Unable to open target file:" : PRINT : PRINT "           "; FLA$
  105. 1510 LOCATE 11,3 :PRINT "Possible reasons:" : PRINT :PRINT "              Bad filename": PRINT :PRINT "              No room on diskette" : PRINT :PRINT "              No room in directory"
  106. 1520 LOCATE 22,3 : PRINT "(Press any key to continue.)"
  107. 1530 GOSUB 1260 : CLOSE : GOTO 10
  108.